; -*- tab-width: 4 -*-
; 19.2Kbps Serial Bitbang Routine
; For use on HOODMICRO PIC12F6XX at 4MHz
;
; Copyright (c) 2005, K9spud LLC.
; http://www.k9spud.com/hoodmicro/
;
; This program is free software; you can redistribute it and/or
; modify it under the terms of the GNU General Public License
; as published by the Free Software Foundation; either version 2
; of the License, or (at your option) any later version.
;
; This program is distributed in the hope that it will be useful,
; but WITHOUT ANY WARRANTY; without even the implied warranty of
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
; GNU General Public License for more details.
;
; You should have received a copy of the GNU General Public License
; along with this program; if not, write to the Free Software
; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
	
	processor	12F629

TX_PIN	equ	2

STATUS	equ	3
Z		equ	2
C		EQU	0
GPIO	equ	5
INTCON	equ	0x0B
GIE		equ	7

	global	_putch
	signat	_putch,4216
	psect	text0,local,class=CODE,delta=2
	psect	text0

	;; ?a_putch+0 - sendbyte
	;; ?a_putch+1 - sendbitcount
_putch:
	movwf	?a_putch+0			; save the byte to send to local data space
	movlw	-9					; send 8 bits
	movwf	?a_putch+1

SerialSend:
	bcf		INTCON, GIE		; disable interrupts, timing critical code
	movf	GPIO, w

;; Number of clock cycles (at 1us per clock) for 19.2Kbps serial send:
;; 56us too slow, garbage
;; 54us works
;; 52us works - recommended setting
;; 50us works
;; 48us too fast, garbage

	; initially send start bit
LowBit:
	iorlw	(1<<TX_PIN)
	movwf	GPIO			; 1
	call	Wait22
	call	Wait21

BitCount:
	incf	?a_putch+1, f ; 1
	btfsc	STATUS, Z		; 1 2 exit loop if we've transferred 8 bits already
	goto    StopBit			; 2

	rrf		?a_putch+0, f		; 1 load next bit into carry flag
	btfss	STATUS, C       ; 1 2
	goto	LowBit          ; 2

	andlw	~(1<<TX_PIN)  ; 1
	nop
	movwf	GPIO			; 1
	call	Wait21
	call	Wait20
	goto    BitCount        ; 2

StopBit:
	goto    $+1				; 2
	andlw	~(1<<TX_PIN)
	movwf	GPIO
	bsf		INTCON, GIE		; enable interrupts, timing critical code done
	call	Wait22
	call	Wait22
	return
	FNSIZE	_putch,2,0
	global	?a_putch
	
;--------------------------------------------------------------------------
; WaitXX - Burns cpu cycles for timing purposes. XX = number of cycles
;--------------------------------------------------------------------------
Wait21:	nop
		goto	Wait18
Wait22:	goto    $+1				; 22
Wait20:	goto    $+1				; 20
Wait18:	goto    $+1				; 18
Wait16:	goto    $+1				; 16
Wait14:	goto    $+1				; 14
Wait12:	goto    $+1				; 12
Wait10:	goto    $+1				; 10
Wait8:	goto    $+1				; 8
Wait6:	goto    $+1				; 6
		return					; 4 (initial call used 2)
	
	psect	text1,local,class=CODE,delta=2
	psect	text1
	end